x [GUIGUI01/memo30] - OSASK計画

印刷

ぐいぐい01に関するメモ-30 ^[1]

(by K^[2], 2009.08.03)
メモのうち重要な部分をそのうちまとめてまともなページを作る

(42) naskで.g01アプリを作るには？(1) ^[3]

impressions^[4]の2009-07-26ごろのfshinoさんのリクエストに答えるために、このセクションは用意されました。
文脈的にはGUIGUI01/memo27^[5]の続きだけど、あっちはC言語。こっちはアセンブラ主体です。

何はともあれ、まずは文字列表示を使って"hello, world\n"をやってみることにします。・・・あれ？GUIGUI01/memo18^[6]に今から僕が書こうとしていることに近いことが書いてありますね。ああでも、今回はサイズ重視ではなく、汎用かつ簡潔性重視で行きます。

; ex0025.nas
[FORMAT "WCOFF"]
[FILE "ex0025.nas"]
[INSTRSET "i486p"]
[BITS 32]
        GLOBAL  _G01Main
        EXTERN  _g01_execcmd0

[SECTION .text]

_G01Main:
        MOV     EAX,msg
        CALL    _g01_execcmd0
        DB      0x53, 0x00     ; g01_putstr0((char *) EAX);
        RET

[SECTION .data]

msg     DB      "hello, world", 0x0a, 0

これです。makeすると64バイトになるでしょう。MakefileはGUIGUI01/memo18^[6]のex0000の例を参考にしてください。
要点は次の通りです。
- 「CALL _g01_execcmd0 DB 0x53, 0x00」が、EAX番地からの文字列表示API
- （ポインタで指定する）文字列は.dataかもしくはスタック内に置かなければいけない。
- 「CALL _g01_execcmd0」すると、ESIはある特別な値が代入され、EDIは強制的に0になる。これが困る場合は、PUSHなどでレジスタを退避すること。
  - 他のレジスタは原則として影響がない。
- CALLのあとにDBがあるのが気持ち悪いが、EDI=0でAPIを呼んでいる時は、これを読み飛ばしたアドレスにRET先が自動修正されてからRETするので、心配しなくていい。
  - というか、そのために_g01_execcmd0は内部でEDI=0にしてからAPIを呼んでいる。詳しくは後述。
- アプリの実行開始番地は_G01Mainに固定。
EAX以外のレジスタを指定したい場合は次の通りです。
- 「CALL _g01_execcmd0 DB 0x53, 0x10」が、ECX番地からの文字列表示API
- 「CALL _g01_execcmd0 DB 0x53, 0x20」が、EDX番地からの文字列表示API
- 「CALL _g01_execcmd0 DB 0x53, 0x30」が、EBX番地からの文字列表示API

次は1文字表示APIです。

; ex0026.nas
[FORMAT "WCOFF"]
[FILE "ex0026.nas"]
[INSTRSET "i486p"]
[BITS 32]
        GLOBAL  _G01Main
        EXTERN  _g01_execcmd0

[SECTION .text]

_G01Main:
        MOV     AL,0x20
.putc_loop
        CALL    _g01_execcmd0
        DB      0x55, 0x16, 0x00     ; g01_putc(EAX);
        INC     EAX
        CMP     AL,0x7e
        JBE     .putc_loop
        MOV     AL,0x0a
        CALL    _g01_execcmd0
        DB      0x55, 0x16, 0x00     ; g01_putc(EAX);
        RET

これです。makeすると57バイトになるでしょう。
要点は次の通りです。
- 「CALL _g01_execcmd0 DB 0x55, 0x16, 0x00」が、putc(EAX);相当のAPI
ちなみにこれもレジスタを選べます。
- 「CALL _g01_execcmd0 DB 0x55, 0x16, 0x10」が、putc(ECX);相当のAPI
- 「CALL _g01_execcmd0 DB 0x55, 0x16, 0x20」が、putc(EDX);相当のAPI
- 「CALL _g01_execcmd0 DB 0x55, 0x16, 0x30」が、putc(EBX);相当のAPI
こんな感じで分かるでしょうか？

ここで、「CALL _g01_execcmd0」の正体を明かしたいと思います。これはライブラリで用意されている関数なのですが、中身はこうなっています。

        EXTERN _g01_esi0

_g01_execcmd0:
        XOR     EDI,EDI
        MOV     ESI,[_g01_esi0]
        JMP     [ESI]           ; これがAPI呼び出し。RETで帰ると_g01_execcmd0の呼び出し元へ帰る。

だからEDIが0になるとか、ESIの値が上書きされるなんてことになっていたわけです。

これを利用すると、ex0026.nasは次のように書き換えられます。

; ex0026.nas
[FORMAT "WCOFF"]
[FILE "ex0026.nas"]
[INSTRSET "i486p"]
[BITS 32]
        GLOBAL  _G01Main
        EXTERN  _g01_esi0

[SECTION .text]

_G01Main:
        MOV     AL,0x20
        XOR     EDI,EDI
        MOV     ESI,[_g01_esi0]
.putc_loop
        CALL    [ESI]
        DB      0x55, 0x16, 0x00     ; g01_putc(EAX);
        INC     EAX
        CMP     AL,0x7e
        JBE     .putc_loop
        MOV     AL,0x0a
        CALL    [ESI]
        DB      0x55, 0x16, 0x00     ; g01_putc(EAX);
        RET

これです。makeすると56バイトになるでしょう。ちょっとだけ小さくなったわけです。

さらに小さくすることもできます。実は.g01アプリが実行される際には、EDI=0,ESI=[_g01_esi0]の初期値で始まることが保証されているのです。つまり、_G01Main:に入った時点でこれらの値は保証されているので、わざわざ初期化する必要はないのです。そうすると、こう書けます。

; ex0026.nas
[FORMAT "WCOFF"]
[FILE "ex0026.nas"]
[INSTRSET "i486p"]
[BITS 32]
        GLOBAL  _G01Main

[SECTION .text]

_G01Main:
        MOV     AL,0x20
.putc_loop
        CALL    [ESI]
        DB      0x55, 0x16, 0x00     ; g01_putc(EAX);
        INC     EAX
        CMP     AL,0x7e
        JBE     .putc_loop
        MOV     AL,0x0a
        CALL    [ESI]
        DB      0x55, 0x16, 0x00     ; g01_putc(EAX);
        RET

短くなりました。
このテクニックは、もちろんex0025.nasにも有効です。今後はいちいち書きませんが、どのAPIにも使えます。

次は文字列定数の表示です。
ex0025では、文字列のアドレスをレジスタを使って渡したわけですが、それはAPIとしては文字列のアドレスが可変という自由度があるわけです。しかしもしex0025のように、実際は単に文字列定数を表示しているだけなら、そんな自由度はいりません。その場合は次のようにコードを減らせます。またこの記法では、EAXレジスタも使わなくなるので、その点でも有利です。
```
; ex0027.nas
[FORMAT "WCOFF"]
[FILE "ex0027.nas"]
[INSTRSET "i486p"]
[BITS 32]
        GLOBAL  _G01Main
        EXTERN  _g01_execcmd0

[SECTION .text]

_G01Main:
        CALL    _g01_execcmd0
        DB      0x51, "hello, world", 0x0a, 0x00     ; g01_putstr0("hello, world\n");
        RET
```
これはmakeすると57バイトになるでしょう。ex0025と比べて7バイトも減りました。このやり方の場合、文字列は当然.text内に置くことになります。
要点は次の通りです。
- 「CALL _g01_execcmd0 DB 0x51, ...」が、g01_putstr0(...);相当のAPI
- 文字列なので終端の0x00を忘れずに。
ちなみにここでは紹介していませんが、先の0x53でもこの0x51でも、終端のコードを0x00以外にさせる方法もあります。またどちらも終端文字コードを使わずに、文字列長使って表示させる方法もあります。要望があれば紹介します。
この手法は、当然ex0026の末尾の改行コード出力にも使えます。わざわざAL=0x0a;なんてやってAPIを呼ぶ必要なんてないのです。

こめんと欄 ^[7]

Last-modified: 2009-11-21 (土) 00:00:00 (JST) (319d) by k-tan

Links list

(This host) = http://osask.net

^{(This host)}/modules/osaskwiki/235.html#jd166c93
^{(This host)}/modules/osaskwiki/144.html
^{(This host)}/modules/osaskwiki/235.html#d8843b70
^{(This host)}/modules/osaskwiki/354.html
^{(This host)}/modules/osaskwiki/346.html
^{(This host)}/modules/osaskwiki/442.html
^{(This host)}/modules/osaskwiki/235.html#g4dd4525

GUIGUI01​/memo30 :: OSASK計画

ぐいぐい01に関するメモ-30 [1]

(42) naskで.g01アプリを作るには？(1) [3]

こめんと欄 [7]

Links list

GUIGUI01/memo30 :: OSASK計画

ぐいぐい01に関するメモ-30 ^[1]

(42) naskで.g01アプリを作るには？(1) ^[3]

こめんと欄 ^[7]